Crosscountry USA Photo Safari/Crosscountry USA Photo Safari.iso/Data/cc_base/pak00_16bit_f.pk3/splash_screen.gl.p

Text File | 2003-04-14 | 6KB | 184 lines

{
  ActiveWhileHidden = TRUE;

  ScriptID = script {

      @loaded {
        resid main_menu;

        /* show more_info and buy_it buttons if this is a demo */
        if (CVarGetInt("demo") == 1) {
          ResPropSetInt(GuiChildByName(SELF,"buy_it"),"Hidden",FALSE);
          ResPropSetInt(GuiChildByName(SELF,"more_info"),"Hidden",FALSE);
        }


        /* pre load all of the menus */
        main_menu = ResByName("main_menu.gl");
        ResByName("game_setup.gl");
        ResByName("game_options.gl");
        ResByName("credits.gl");
      ResByName("load_saved_game.gl");
      ResByName("load_scenario.gl");
    }
  };

  ChildID = {
    GuiMenuController("menu_controller") {
      ScriptID = script {
        @loaded {
          ResPropSetInt(SELF,"state",-1);
        }
        @animate {
          resid panel_to_display;
          resid panel_being_displayed;
          resid sound;
          resid reverse_sound;
          int panel_to_display_x;
          int panel_to_display_y;
          int panel_being_displayed_x;
          int panel_being_displayed_y;
          int panel_to_display_width;
          int panel_being_displayed_width;
          int speed;
          int state;
          int timeout;

          /*
           -2 = startup wait
           -1 = startup
           0  = stop
           1  = to hide
           2  = to show
          */


          speed = 65;
          sound = ResByName("sound/menu_swipe.wav");
          reverse_sound = ResByName("sound/menu_swipe_reverse.wav");
          ResPropAlias(SELF, "panel_to_display", "panel_to_display");
          ResPropAlias(SELF, "panel_being_displayed", "panel_being_displayed");
          ResPropAlias(panel_being_displayed,"X","panel_being_displayed_x");
          ResPropAlias(panel_being_displayed,"Y","panel_being_displayed_y");
          ResPropAlias(panel_to_display,"X","panel_to_display_x");
          ResPropAlias(panel_to_display,"Y","panel_to_display_y");
          ResPropAlias(panel_to_display,"Width","panel_to_display_width");
          ResPropAlias(panel_being_displayed,"Width","panel_being_displayed_width");
          ResPropAlias(SELF,"state","state");
          ResPropAlias(SELF,"timeout","timeout");

          if (state==-1) {

            if (CVarGetInt("horn_played") != 1) {
              AudioPlay(ResByName("sound/horn.wav"));
              CVarSetInt("horn_played",1);
            }
            timeout = CVarGetInt("framerate")*1;
            state = -2;
            stop;
          }

          if (state==-2) {
            if (timeout<=0) {
              panel_to_display = ResByName("main_menu.gl");
              ResPropSetInt(panel_to_display, "X", (-ResPropGetInt(panel_to_display, "Width")) - 20);
              ResPropSetInt(panel_to_display, "Y", 20);
              ResPropSetInt(panel_to_display, "Hidden", FALSE);
              state=2;
              stop;
            }
            timeout -= 1;
            stop;
          }

          if (panel_to_display != panel_being_displayed) {

            /* set the state to pan left and put the one being displayed off screen*/
            if (state == 0) {
              AudioPlay( sound );
              panel_to_display_x = (panel_to_display_width * -1) - 200;
              panel_to_display_y = 20;
              state = 1;
            }

            if (state == 1) {
              if ((panel_being_displayed_x + panel_being_displayed_width) < 0) {
                AudioPlay( reverse_sound );
                state = 2;
                ResPropSetInt(panel_being_displayed, "Hidden", TRUE);
                ResPropSetInt(panel_to_display, "Hidden", FALSE);
                stop;
              } else {
                panel_being_displayed_x = panel_being_displayed_x - speed;
              }
            }

            if (state == 2) {
              if (panel_to_display_x < 20) {
                if ((panel_to_display_x + speed) > 20 ) {
                  panel_to_display_x = 20;
                } else {
                  panel_to_display_x = panel_to_display_x + speed;
                }
              } else {
                panel_being_displayed = panel_to_display;
                state = 0;
              }
            }
          }
        }
      }
    },



    GuiAnimation("background") {
      AnimationID = "image/splash.jpg";
      X = 0;
      Y = 0;
      ScriptID = Script {
        @loaded {
          CVarSetStr("dataversion", CSVGetStr(ResPropGetResID(ResByName("CSVData"), "version_id"), "data_version", 0));
        }
        @draw {
          int ver;
          ver = Version();
          DrawTextStr(ResByName("font/arial_12.tf"), 12, 468, "Atlas Version: %d.%d  Data Version: %s", ver / 256, ver % 256, CVarGetStr("dataversion"));
        }
      }
    },


        GuiButton("more_info") {
      X = 446;
      Y = 284;
      Hidden = TRUE;
      UpID = "gui/main_menu/demo/more_info_up.jpg";
      HilightedID = "gui/main_menu/demo/more_info_over.jpg";
      ScriptID = Script {
        @activate {
          if (! BrowserOpenURL(CVarGetStr("demo_information_link"))) {
            LogStr(LOG_DEBUG,"OPEN BROWSER FAILED:%s\n",CVarGetStr("demo_information_link"));
          }
        }
      }
    },
        GuiButton("buy_it") {
      X = 446;
      Y = 320;
      Hidden = TRUE;
      UpID = "gui/main_menu/demo/buy_it_up.jpg";
      HilightedID = "gui/main_menu/demo/buy_it_over.jpg";
      ScriptID = Script {
        @activate {
          if (! BrowserOpenURL(CVarGetStr("demo_purchase_link"))) {
            LogStr(LOG_DEBUG,"OPEN BROWSER FAILED:%s\n",CVarGetStr("demo_purchase_link"));
          }
        }
      }
    };


  };  /* end of layer */
}